MASURARI IN ELECTRONICA - Circuite de baza cu AO

UNIVERSITATEA DIN PITESTI

Facultatea de ELECTRONICA, COMUNICATII SI CALCULATOARE

MASURARI IN ELECTRONICA

Lucrarea nr. 2

Circuite de baza cu AO

Amplificator inversor

*AMPLIFICATOR

*INVERSOR

R1 1 3 50K

R3 3 5 50k

R4 4 0 100K

X1 4 3 6 7 5 UA741

.LIB opamp.LIB

VCC 6 0 DC 15V

VEE 0 7 DC 15V

V1 1 0 SIN(0 3 50)

.TRAN 0.2M 100M

.PROBE

.END

Cu amplificare de 3 ori mai mare, R3 3 5 150k.

Cu amplificare de 30 de ori mai mare, R3 3 5 1.5MEG.

Amplificator neinversor

*AMPLIFICATOR

*NEINVERSOR

R1 0 3 5K

R2 3 5 10k

R3 1 4 5K

X1 4 3 6 7 5 UA741

.LIB opamp.LIB

VCC 6 0 DC 15V

VEE 0 7 DC 15V

V1 1 0 SIN(0 3 50)

.TRAN 0.2M 100M

.PROBE

.END

Cu amplificare de 3 ori.

Repetor de tensiune

*REPETOR DE

*TENSIUNE

R1 1 4 5K

R2 2 3 5k

X1 3 1 5 6 4 UA741

.LIB opamp.LIB

VCC 5 0 DC 15V

VEE 0 6 DC 15V

V1 2 0 SIN(0 3 50)

.TRAN 0.2M 100M

.PROBE

.END

Amplificator sumator

*AMPLIFICATOR

*SUMATOR

R1 1 4 50K

R2 2 4 50k

R3 3 4 50K

R4 4 6 50K

R5 0 5 100K

X1 5 4 7 8 6 UA741

.LIB opamp.LIB

VCC 7 0 DC 15V

VEE 0 8 DC 15V

V1 1 0 SIN(0 3 50)

V2 2 0 SIN(0 1 100)

V3 3 0 SIN(0 1 1000)

.TRAN 0.2M 100M

.PROBE

.END

Amplificator diferential

*AMPLIFICATOR

*DIFERENTIAL

R1 1 3 50K

R3 3 5 150k

R2 2 4 50K

R4 4 0 150K

X1 4 3 6 7 5 UA741

.LIB opamp.LIB

VCC 6 0 DC 15V

VEE 0 7 DC 15V

V1 1 0 SIN(0 3 50)

V2 2 0 SIN(0 1 300)

.TRAN 0.2M 100M

.PROBE

.END

Amplificator integrator

*AMPLIFICATOR

*INTEGRATOR

R1 1 2 50K

R2 3 0 50K

C1 2 4 1N

X1 3 2 5 6 4 UA741

.LIB opamp.LIB

VCC 5 0 DC 15V

VEE 0 6 DC 15V

V1 1 0 SIN(0 0.1 50)

.TRAN 0.2M 100M

.PROBE

.END

Amplificator derivator

*AMPLIFICATOR

*DERIVATOR

C1 1 2 1N

R1 2 4 50K

R2 3 0 50K

X1 3 2 5 6 4 UA741

.LIB opamp.LIB

VCC 5 0 DC 15V

VEE 0 6 DC 15V

V1 1 0 SIN(0 0.1 50)

.TRAN 0.2M 100M

.PROBE

.END

Convertor tensiune-curent

*CONVERTOR

*TENSIUNE-CURENT

R1 1 2 50K

R2 2 4 50K

R3 3 0 25K

X1 3 2 5 6 4 UA741

.LIB opamp.LIB

VCC 5 0 DC 15V

VEE 0 6 DC 15V

V1 1 0 SIN(0 3 50)

.TRAN 0.2M 100M

.PROBE

.END

Convertor curent-tensiune

*CONVERTOR

*CURENT-TENSIUNE

R2 2 4 50K

R3 3 0 50K

X1 3 2 5 6 4 UA741

.LIB opamp.LIB

VCC 5 0 DC 15V

VEE 0 6 DC 15V

V2 2 0 SIN(0 3 50)

.TRAN 0.2M 100M

.PROBE

.END

Amplificator logaritmic

*AMPLIFICATOR

*LOGARITMIC

R1 1 2 30K

R2 3 0 30K

D1 2 4 D1N4148

.LIB diode.lib

X1 3 2 5 6 4 uA741

.LIB opamp.LIB

VCC 5 0 DC 15V

VEE 0 6 DC 15V

V1 1 0 SIN(0 3 50)

.TRAN 0.1M 100M

.PROBE

.END

Amplificator exponential

*AMPLIFICATOR

*EXPONENTIAL

R1 2 4 30K

R2 3 0 30K

D1 1 2 D1N4148

.LIB diode.lib

X1 3 2 5 6 4 uA741

.LIB opamp.LIB

VCC 5 0 DC 15V

VEE 0 6 DC 15V

V1 1 0 SIN(0 3 50)

.TRAN 0.2M 100M

.PROBE

.END